// Nonsingularity assertions of Theorem 1.1.


// (0) The 9-fold V has singular locus
// AA^4<r0,r1,r2,s> union the 3 planes AA^2<xi,ri>

RR<r0,r1,r2,S,x0,x1,x2, y0,y1,y2, z0,z1,z2>
 := PolynomialRing(Rationals(),[2,2,2,3,1,1,1,2,2,2,3,3,3]);

L := [
S*x0*x2 + r0*x2*y0 + r2*x0*y2 - y1*z1,
-r1*r2*x0^2 - S*x0*y0 - r0*y0^2 + z1*z2,
S*x0*x1 + r0*x1*y0 + r1*x0*y1 - y2*z2,
-r1*x0*x2 + y0*y2 - x1*z1,
r2*x0*x1 - y0*y1 + x2*z2,
-(-r0*x1*x2 + y1*y2 - x0*z0),
-(r0*r2*x1^2 + S*x1*y1 + r1*y1^2 - z0*z2),
-(S*x1*x2 + r1*x2*y1 + r2*x1*y2 - y0*z0),
-(r0*r1*x2^2 + S*x2*y2 + r2*y2^2 - z0*z1)
];

J := JacobianMatrix(L);

RRbar<r0,r1,r2,S,x0,x1,x2>
 := PolynomialRing(Rationals(),[2,2,2,3,1,1,1]);
fie := hom<RR -> RRbar | r0,r1,r2,S,x0,x1,x2,0,0,0,0,0,0>;
Jbar := Matrix(13,[ fie(J[i,j]) : j in [1..13], i in [1..9] ]);
V := ReducedSubscheme(Scheme(Spec(RRbar), fie(L) cat Minors(Jbar,4)));
Dimension(V);
X := IrreducibleComponents(V);
X[1];
[Dimension(x) : x in X];
X[2];


// (A) The S3 symmetric surface Y univeral cover of the
// ZZ/3 Godeaux is nonsingular, and ZZ/3 action is free

RR<x1,x2, y0,y1,y2, z1,z2>
 := PolynomialRing(Rationals(),[1,1,2,2,2,3,3]);

x0 := -x1 - x2;
z0 := -z1 - z2;
r0 := y0 + x0^2 + 7*x1*x2;
r1 := y1 + x1^2 + 7*x0*x2;
r2 := y2 + x2^2 + 7*x0*x1;
s := x0^3 + x1^3 + x2^3;

L := [
s*x0*x2 + r0*x2*y0 + r2*x0*y2 - y1*z1,
-r1*r2*x0^2 - s*x0*y0 - r0*y0^2 + z1*z2,
s*x0*x1 + r0*x1*y0 + r1*x0*y1 - y2*z2,
-r1*x0*x2 + y0*y2 - x1*z1,
r2*x0*x1 - y0*y1 + x2*z2,
-(-r0*x1*x2 + y1*y2 - x0*z0),
-(r0*r2*x1^2 + s*x1*y1 + r1*y1^2 - z0*z2),
-(s*x1*x2 + r1*x2*y1 + r2*x1*y2 - y0*z0),
-(r0*r1*x2^2 + s*x2*y2 + r2*y2^2 - z0*z1)
];

J := JacobianMatrix(L);
JJ := Minors(J,4);
time z0^4 in Ideal(JJ); // true. Time = 1.3 secs
time y0^5 in Ideal(JJ cat [z0,z1,z2]); // true. Time = 0.8 secs
time x0^13 in Ideal(JJ cat [z0,z1,z2,y0,y1,y2]); // true 0.8 secs

// The ZZ/3 action on Y is fixed point free

Fix := L cat [x1^3-x0^3, x2^3-x1^3, y1^3-y0^3, y2^3-y1^3, z1-z0, z2-z1];
Dimension(Scheme(Proj(RR), Fix)); // gives -1, the empty set

time y0^4 in Ideal(Fix); // true 0 secs
time x0^8 in Ideal(Fix); // true 0 secs


// (B) The S3 symmetric 4-fold F of index 3 is quasismooth

RR<x0,x1,x2, y0,y1,y2, z0,z1,z2>
 := PolynomialRing(Rationals(),[1,1,1,2,2,2,3,3,3]);

r0 := y0 + x0^2 + 7*x1*x2;
r1 := y1 + x1^2 + 7*x0*x2;
r2 := y2 + x2^2 + 7*x0*x1;
s := x0^3 + x1^3 + x2^3;

L := [
s*x0*x2 + r0*x2*y0 + r2*x0*y2 - y1*z1,
-r1*r2*x0^2 - s*x0*y0 - r0*y0^2 + z1*z2,
s*x0*x1 + r0*x1*y0 + r1*x0*y1 - y2*z2,
-r1*x0*x2 + y0*y2 - x1*z1,
r2*x0*x1 - y0*y1 + x2*z2,
-(-r0*x1*x2 + y1*y2 - x0*z0),
-(r0*r2*x1^2 + s*x1*y1 + r1*y1^2 - z0*z2),
-(s*x1*x2 + r1*x2*y1 + r2*x1*y2 - y0*z0),
-(r0*r1*x2^2 + s*x2*y2 + r2*y2^2 - z0*z1)
];

J := JacobianMatrix(L);
JJ := Minors(J,4);
time z0^4 in Ideal(JJ); // true. Time = 11 secs
time y0^5 in Ideal(JJ cat [z0,z1,z2]); // true. Time = 11 secs
time x0^13 in Ideal(JJ cat [z0,z1,z2,y0,y1,y2]); // true 10 secs


// (C) The S3 symmetric Calabi-Yau is nonsingular

RR<x0,x1,x2, y0,y1,y2, z1,z2>
 := PolynomialRing(Rationals(),[1,1,1,2,2,2,3,3]);

z0 := -z1 - z2;
r0 := y0 + x0^2 + 7*x1*x2;
r1 := y1 + x1^2 + 7*x0*x2;
r2 := y2 + x2^2 + 7*x0*x1;
s := x0^3 + x1^3 + x2^3;

L := [
s*x0*x2 + r0*x2*y0 + r2*x0*y2 - y1*z1,
-r1*r2*x0^2 - s*x0*y0 - r0*y0^2 + z1*z2,
s*x0*x1 + r0*x1*y0 + r1*x0*y1 - y2*z2,
-r1*x0*x2 + y0*y2 - x1*z1,
r2*x0*x1 - y0*y1 + x2*z2,
-(-r0*x1*x2 + y1*y2 - x0*z0),
-(r0*r2*x1^2 + s*x1*y1 + r1*y1^2 - z0*z2),
-(s*x1*x2 + r1*x2*y1 + r2*x1*y2 - y0*z0),
-(r0*r1*x2^2 + s*x2*y2 + r2*y2^2 - z0*z1)
];

J := JacobianMatrix(L);
JJ := Minors(J,4);
time z0^4 in Ideal(JJ); // true. Time = 6 secs
time y0^5 in Ideal(JJ cat [z0,z1,z2]); // true. Time = 4 secs
time x0^13 in Ideal(JJ cat [z0,z1,z2,y0,y1,y2]); // true 3 secs


// (D) The S3 symmetric Fano of index 2 is quasismooth

RR<x1,x2, y0,y1,y2, z0,z1,z2>
 := PolynomialRing(Rationals(),[1,1,1,2,2,2,3,3]);

x0 := -x1 - x2;
r0 := y0 + x0^2 + 7*x1*x2;
r1 := y1 + x1^2 + 7*x0*x2;
r2 := y2 + x2^2 + 7*x0*x1;
s := x0^3 + x1^3 + x2^3;

L := [
s*x0*x2 + r0*x2*y0 + r2*x0*y2 - y1*z1,
-r1*r2*x0^2 - s*x0*y0 - r0*y0^2 + z1*z2,
s*x0*x1 + r0*x1*y0 + r1*x0*y1 - y2*z2,
-r1*x0*x2 + y0*y2 - x1*z1,
r2*x0*x1 - y0*y1 + x2*z2,
-(-r0*x1*x2 + y1*y2 - x0*z0),
-(r0*r2*x1^2 + s*x1*y1 + r1*y1^2 - z0*z2),
-(s*x1*x2 + r1*x2*y1 + r2*x1*y2 - y0*z0),
-(r0*r1*x2^2 + s*x2*y2 + r2*y2^2 - z0*z1)
];

J := JacobianMatrix(L);
JJ := Minors(J,4);
time z0^4 in Ideal(JJ); // true. Time = 2.4 secs
time y0^5 in Ideal(JJ cat [z0,z1,z2]); // true. Time = 2.2 secs
time x0^13 in Ideal(JJ cat [z0,z1,z2,y0,y1,y2]); // true 2.2 secs